-------------------------------------------------------------------------------
Also see  regex.hints  for hints and tips of matching regular expressions
-------------------------------------------------------------------------------
EXAMPLE:
  The best hint for a difficult script command is a good example This
  sed script grabs a `face' file (which always starts with a space or
  tab)  and repositions it correctly at the end of the mail header
  (denoted by a absolutely blank line). NOTE the use of lables.

  cat $FACE - $SIGNED | sed -n '
    # first collect the new face at the start of the input
    1 { s/^/X-Face:/; h; d; }
      /^[ 	]/{H;d;}
    # read the header; if X-face found just copy all
    : head
      /^X-Face:/ b body
      /^$/ b face
      p; n; b head
    # output a face at end of header
    :face
      x; p; g; p; n
    # just copy the rest of the file
    : body
      p; n; b body
  ' | /lib/sendmail "$@"

-------------------------------------------------------------------------------
Adding a newline to sed (just add return -- messy)
  bourne shells:
       sed 's/;$/; }\
       /' filename

  Csh family:
       sed 's/;$/; }\\
       /' filename

Of course you can always use a tr which is slower but neater

      sed 's/;$/; }@/' | tr '@' '\012'

-------------------------------------------------------------------------------
Moving a line to the start of the file
EG
     something1                          this
     something2            ====>         something1
     this                                something2
     something3                          something3

  sed -n '
    /this/!H                      # if no match append to hold space
    /this/{x; H; }                # found so exhange and append (prepend)
    ${g; s/\n//; p; }' <infile    # if last line get and print hold
OR
  sed '1,/this/{                  # until found
    /this/!{H; d; }               # if not it put in hold (no print)
    G; s-\n--; }' infile          # output hold - continue print with the rest

-------------------------------------------------------------------------------
Counting lines ("sed" only no "wc")
    sed -n '$=' file

-------------------------------------------------------------------------------
Word Division -- with out using sed

    Name=`echo $DISPLAY | sed 's/:.*//'`

can be done faster with

    oldIFS=$IFS; IFS=.; set -- $DISPLAY; IFS=$oldIFS; Name=$1;

no fork, totally internal to shell

------------------------------------------------------------------------------
Delimiting "sed" Delimetors (also see next)

Say you want to search for a path name that contains slashes `/'
unfortunatally these are the sed regular expresion delimiters so you
need to escape the slashes before you can search for it. This is not as
easy as it sounds.


old_path="/some/path/to/look/for"
new_path="/some/path/to/look/for"

old_path=`echo "$old_path" | sed 's/\//\\\\\//g'`
new_path=`echo "$new_path" | sed 's/\//\\\\\//g'`

sed 's'"$old_path"'/'"$new_path"'/g' $old_file > $new_file

-------------------------------------------------------------------------------
Sed with arbatitry patterns

>#!/bin/sh
>sed 's/'"$1"'/'"$2"'/g

That's OK provided you know for certain that $1 will never contain a "/"
or "\", and $2 will never contain a "/", "\" or "&".  If $1 and $2 are
completely arbitrary you need to do something like:

    pat=`echo "$1" | sed 's:[/\\]:\\&:g'`
    rep=`echo "$2" | sed 's:[/\\&]:\\&:g'`
    sed "s/$pat/$rep/g"

problem with  """ or "`" in patterns ????

------------------------------------------------------------------------------
Delete between marker 1 and marker2
file
  ...
  MARKER 1
  ...
  MARKER 2
  ...
then
[]      inclusive delete:
                $ sed <foo -e '/^UNIQUE MARKER 1$/,/^UNIQUE MARKER 2$/d'

()      exclusive delete:
                $ sed <foo -e '
                        /^UNIQUE MARKER 1$/,/^UNIQUE MARKER 2$/{
                                /^UNIQUE MARKER 1$/!{
                                        /^UNIQUE MARKER 2$/!d
                                }
                        }'

[)      exclude marker 2
                $ sed <foo -e '
                        /^UNIQUE MARKER 1$/,/^UNIQUE MARKER 2$/{
                                /^UNIQUE MARKER 2$/!d
                        }'

(]      exclude marker 1
                $ sed <foo -e '
                        /^UNIQUE MARKER 1$/,/^UNIQUE MARKER 2$/{
                                /^UNIQUE MARKER 1$/!d
                        }'

See also regex.hints for in-line delimited text.

------------------------------------------------------------------------------